Function: ispell-ignore-fcc

ispell-ignore-fcc is a byte-compiled function defined in ispell.el.gz.

Signature

(ispell-ignore-fcc START END)

Documentation

Query whether to delete Fcc header due to attachment between START and END.

Query the user whether Fcc header should be deleted when large attachments are included in the message. Return nil if email with large attachments should be saved. This can be used to avoid multiple questions for multiple large attachments. Return point to starting location afterwards.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/ispell.el.gz
(defun ispell-ignore-fcc (start end)
  "Query whether to delete Fcc header due to attachment between START and END.
Query the user whether Fcc header should be deleted when large attachments are
included in the message.
Return nil if email with large attachments should be saved.
This can be used to avoid multiple questions for multiple large attachments.
Return point to starting location afterwards."
  (let ((result t))
    (if (and ispell-checking-message ispell-message-fcc-skip)
	(if (< ispell-message-fcc-skip (- end start))
	    (let (case-fold-search head-end)
	      (goto-char (point-min))
	      (setq head-end
		    (or (re-search-forward
			 (concat "^" (regexp-quote mail-header-separator) "$")
			 nil t)
			(re-search-forward "^$" nil t)
			(point-min)))
	      (goto-char (point-min))
	      (if (re-search-forward "^Fcc:" head-end t)
		  (if (y-or-n-p
		       "Save copy of this message with large attachments? ")
		      (setq result nil)
		    (beginning-of-line)
		    (kill-line 1)))
	      (goto-char end))))
    result))