Function: kmacro-menu-edit-column

kmacro-menu-edit-column is an interactive and byte-compiled function defined in kmacro.el.gz.

Signature

(kmacro-menu-edit-column)

Documentation

Edit the value in the current column of the keyboard macro at point.

View in manual

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/kmacro.el.gz
(defun kmacro-menu-edit-column ()
  "Edit the value in the current column of the keyboard macro at point."
  (declare (modes kmacro-menu-mode))
  (interactive nil kmacro-menu-mode)
  (kmacro-menu--assert-row)
  (kmacro-menu--query-revert)
  (pcase (get-text-property (point) 'tabulated-list-column-name)
    ('nil        (let ((pos (point)))
                   ;; If we didn't find a column, try moving forwards or
                   ;; backwards to the nearest column.
                   (tabulated-list-next-column 1)
                   (when (= pos (point))
                     (tabulated-list-previous-column 1))
                   (if (null (get-text-property (point) 'tabulated-list-column-name))
                       (user-error "No column at point")
                     (kmacro-menu-edit-column))))
    ("Position"  (call-interactively #'kmacro-menu-edit-position))
    ("Counter"   (call-interactively #'kmacro-menu-edit-counter))
    ("Format"    (call-interactively #'kmacro-menu-edit-format))
    ("Formatted" (user-error "Formatted counter is not editable"))
    ("Keys"      (call-interactively #'kmacro-menu-edit-keys))))