Function: markdown-match-code

markdown-match-code is a byte-compiled function defined in markdown-mode.el.

Signature

(markdown-match-code LAST)

Documentation

Match inline code fragments from point to LAST.

Source Code

;; Defined in ~/.emacs.d/elpa/markdown-mode-20260321.143/markdown-mode.el
(defun markdown-match-code (last)
  "Match inline code fragments from point to LAST."
  (unless (bobp)
    (backward-char 1))
  (when (markdown-search-until-condition
         (lambda ()
           (and
            ;; Advance point in case of failure, but without exceeding last.
            (goto-char (min (1+ (match-beginning 1)) last))
            (not (markdown-in-comment-p (match-beginning 1)))
            (not (markdown-in-comment-p (match-end 1)))
            (not (markdown-code-block-at-pos (match-beginning 1)))))
         markdown-regex-code last t)
    (set-match-data (list (match-beginning 1) (match-end 1)
                          (match-beginning 2) (match-end 2)
                          (match-beginning 3) (match-end 3)
                          (match-beginning 4) (match-end 4)))
    (goto-char (min (1+ (match-end 0)) last (point-max)))
    t))