Function: mh-junk-blocklist-a-msg

mh-junk-blocklist-a-msg is a byte-compiled function defined in mh-junk.el.gz.

Signature

(mh-junk-blocklist-a-msg MESSAGE)

Documentation

Blocklist MESSAGE.

If MESSAGE is nil then the message at point is blocklisted. The hook mh-blocklist-msg-hook is called after you mark a message for blocklisting.

Source Code

;; Defined in /usr/src/emacs/lisp/mh-e/mh-junk.el.gz
(defun mh-junk-blocklist-a-msg (message)
  "Blocklist MESSAGE.
If MESSAGE is nil then the message at point is blocklisted.
The hook `mh-blocklist-msg-hook' is called after you mark a message
for blocklisting."
  (save-excursion
    (if (numberp message)
        (mh-goto-msg message nil t)
      (beginning-of-line)
      (setq message (mh-get-msg-num t)))
    (cond ((looking-at mh-scan-refiled-msg-regexp)
           (error "Message %d is refiled; undo refile before blocklisting"
                  message))
          ((looking-at mh-scan-deleted-msg-regexp)
           (error "Message %d is deleted; undo delete before blocklisting"
                  message))
          ((looking-at mh-scan-allowlisted-msg-regexp)
           (error "Message %d is allowlisted; undo before blocklisting"
                  message))
          ((looking-at mh-scan-blocklisted-msg-regexp) nil)
          (t
           (mh-set-folder-modified-p t)
           (setq mh-blocklist (cons message mh-blocklist))
           (if (not (memq message mh-seen-list))
               (setq mh-seen-list (cons message mh-seen-list)))
           (mh-notate nil mh-note-blocklisted mh-cmd-note)
           (run-hooks 'mh-blocklist-msg-hook)))))