Function: mh-variant-set-variant

mh-variant-set-variant is a byte-compiled function defined in mh-e.el.gz.

Signature

(mh-variant-set-variant VARIANT)

Documentation

Set up the system variables for the MH variant named VARIANT.

If VARIANT is a string, use that key in the alist returned by the function mh-variants(var)/mh-variants(fun). If VARIANT is a symbol, select the first entry that matches that variant.

Source Code

;; Defined in /usr/src/emacs/lisp/mh-e/mh-e.el.gz
(defun mh-variant-set-variant (variant)
  "Set up the system variables for the MH variant named VARIANT.
If VARIANT is a string, use that key in the alist returned by the
function `mh-variants'.
If VARIANT is a symbol, select the first entry that matches that
variant."
  (cond
   ((stringp variant)                   ;e.g. "nmh 1.1-RC1"
    (when (assoc variant (mh-variants))
      (let* ((alist (cdr (assoc variant (mh-variants))))
             (lib-progs (cadr (assoc 'mh-lib-progs alist)))
             (lib       (cadr (assoc 'mh-lib       alist)))
             (progs     (cadr (assoc 'mh-progs     alist)))
             (flists    (cadr (assoc 'flists       alist))))
        ;;(set-default mh-variant variant)
        (setq mh-x-mailer-string     nil
              mh-flists-present-flag flists
              mh-lib-progs           lib-progs
              mh-lib                 lib
              mh-progs               progs
              mh-variant-in-use      variant))))
   ((symbolp variant)                   ;e.g. 'nmh (pick the first match)
    (cl-loop for variant-list in (mh-variants)
             when (eq variant (cadr (assoc 'variant (cdr variant-list))))
             return (let* ((version   (car variant-list))
                           (alist (cdr variant-list))
                           (lib-progs (cadr (assoc 'mh-lib-progs alist)))
                           (lib       (cadr (assoc 'mh-lib       alist)))
                           (progs     (cadr (assoc 'mh-progs     alist)))
                           (flists    (cadr (assoc 'flists       alist))))
                      ;;(set-default mh-variant flavor)
                      (setq mh-x-mailer-string     nil
                            mh-flists-present-flag flists
                            mh-lib-progs           lib-progs
                            mh-lib                 lib
                            mh-progs               progs
                            mh-variant-in-use      version)
                      t)))))