Function: mode-local-describe-bindings-2

mode-local-describe-bindings-2 is a byte-compiled function defined in mode-local.el.gz.

Signature

(mode-local-describe-bindings-2 BUFFER-OR-MODE)

Documentation

Display mode local bindings active in BUFFER-OR-MODE.

Source Code

;; Defined in /usr/src/emacs/lisp/cedet/mode-local.el.gz
(defun mode-local-describe-bindings-2 (buffer-or-mode)
  "Display mode local bindings active in BUFFER-OR-MODE."
  (let (table mode)
    (princ "Mode local bindings active in ")
    (cond
     ((bufferp buffer-or-mode)
      (with-current-buffer buffer-or-mode
        (setq table mode-local-symbol-table
              mode major-mode))
      (princ (format "%S\n" buffer-or-mode))
      )
     ((symbolp buffer-or-mode)
      (setq mode buffer-or-mode)
      (princ (format-message "`%s'\n" buffer-or-mode))
      )
     ((signal 'wrong-type-argument
              (list 'buffer-or-mode buffer-or-mode))))
    (when table
      (princ "\n- Buffer local\n")
      (mode-local-print-bindings table))
    (dolist (mode (derived-mode-all-parents mode))
      (setq table (get mode 'mode-local-symbol-table))
      (when table
        (princ (format-message "\n- From `%s'\n" mode))
        (mode-local-print-bindings table)))))