Function: mouse-generate-font-menu

mouse-generate-font-menu is a byte-compiled function defined in mouse.el.gz.

Signature

(mouse-generate-font-menu)

Documentation

Return a list of menu panes for each font family.

Source Code

;; Defined in /usr/src/emacs/lisp/mouse.el.gz
(defun mouse-generate-font-menu ()
  "Return a list of menu panes for each font family."
  (let ((families (font-family-list))
        (panes (list "Font families")))
    (dolist (family families)
      (when family
        (let* ((fonts (list-fonts (font-spec :family family)))
               (pane (if fonts (list family)
                       (list family (cons family family)))))
          (when fonts
            (dolist (font fonts)
              (setq pane
                    (nconc pane
                           (list (list (or (font-get font :name)
                                           (mouse-generate-font-name-for-menu font))
                                       (font-xlfd-name font)))))))
          (setq panes (nconc panes (list pane))))))
    panes))