Function: org--at-headline-data-p

org--at-headline-data-p is a byte-compiled function defined in org.el.gz.

Signature

(org--at-headline-data-p &optional BEG ELEMENT)

Documentation

Return non-nil when point or BEG is inside headline metadata.

Metadata is planning line, properties drawer, logbook drawer right after property drawer, or clock log line immediately following properties drawer/planning line/ heading.

Optional argument ELEMENT contains element at BEG.

Source Code

;; Defined in /usr/src/emacs/lisp/org/org.el.gz
;;; Indentation

(defun org--at-headline-data-p (&optional beg element)
  "Return non-nil when `point' or BEG is inside headline metadata.

Metadata is planning line, properties drawer, logbook drawer right
after property drawer, or clock log line immediately following
properties drawer/planning line/ heading.

Optional argument ELEMENT contains element at BEG."
  (org-with-wide-buffer
   (when beg (goto-char beg))
   (setq element (or element (org-element-at-point)))
   (if (or (org-element-type-p element 'headline)
           (not (org-element-lineage element '(headline inlinetask))))
       nil ; Not inside heading.
     ;; Skip to top-level parent in section.
     (while (not (org-element-type-p (org-element-parent element) 'section))
       (setq element (org-element-parent element)))
     (pcase (org-element-type element)
       ((or `planning `property-drawer)
        t)
       (`drawer
        ;; LOGBOOK drawer with appropriate name.
        (equal
         (org-log-into-drawer)
         (org-element-property :drawer-name element)))
       (`clock
        ;; Previous element must be headline metadata or headline.
        (goto-char (1- (org-element-begin element)))
        (or (org-at-heading-p)
            (org--at-headline-data-p)))))))