Function: org-ascii-format-inlinetask-default

org-ascii-format-inlinetask-default is a byte-compiled function defined in ox-ascii.el.gz.

Signature

(org-ascii-format-inlinetask-default TODO TYPE PRIORITY NAME TAGS CONTENTS WIDTH INLINETASK INFO)

Documentation

Format an inline task element for ASCII export.

See org-ascii-format-inlinetask-function for a description of the parameters CONTENTS, WIDTH, INLINETASK, and INFO.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ox-ascii.el.gz
;;;; Inlinetask

(defun org-ascii-format-inlinetask-default
    (_todo _type _priority _name _tags contents width inlinetask info)
  "Format an inline task element for ASCII export.
See `org-ascii-format-inlinetask-function' for a description
of the parameters CONTENTS, WIDTH, INLINETASK, and INFO."
  (let* ((utf8p (eq (plist-get info :ascii-charset) 'utf-8))
	 (width (or width (plist-get info :ascii-inlinetask-width))))
    (org-ascii--indent-string
     (concat
      ;; Top line, with an additional blank line if not in UTF-8.
      (make-string width (if utf8p ?━ ?_)) "\n"
      (unless utf8p (concat (make-string width ? ) "\n"))
      ;; Add title.  Fill it if wider than inlinetask.
      (let ((title (org-ascii--build-title inlinetask info width)))
	(if (<= (string-width title) width) title
	  (org-ascii--fill-string title width info)))
      "\n"
      ;; If CONTENTS is not empty, insert it along with
      ;; a separator.
      (when (org-string-nw-p contents)
        (concat (make-string width (if utf8p ?─ ?-)) "\n" contents))
      ;; Bottom line.
      (make-string width (if utf8p ?━ ?_)))
     ;; Flush the inlinetask to the right.
     (- (plist-get info :ascii-text-width) (plist-get info :ascii-global-margin)
	(if (not (org-element-lineage inlinetask 'headline)) 0
	  (plist-get info :ascii-inner-margin))
	(org-ascii--current-text-width inlinetask info)))))