Function: org-babel-execute:emacs-lisp

org-babel-execute:emacs-lisp is a byte-compiled function defined in ob-emacs-lisp.el.gz.

Signature

(org-babel-execute:emacs-lisp BODY PARAMS)

Documentation

Execute emacs-lisp code BODY according to PARAMS.

Aliases

org-babel-execute:elisp

Source Code

;; Defined in /usr/src/emacs/lisp/org/ob-emacs-lisp.el.gz
(defun org-babel-execute:emacs-lisp (body params)
  "Execute emacs-lisp code BODY according to PARAMS."
  (let* ((lexical (cdr (assq :lexical params)))
         (session (cdr (assq :session params)))
	 (result-params (cdr (assq :result-params params)))
	 (body (format (if (member "output" result-params)
			   "(with-output-to-string %s\n)"
			 "(progn %s\n)")
		       (org-babel-expand-body:emacs-lisp body params)))
	 (result (eval (read (if (or (member "code" result-params)
				     (member "pp" result-params))
				 (concat "(pp " body ")")
			       body))
		       (org-babel-emacs-lisp-lexical lexical))))
    (when (and session (not (equal session "none")))
      (error "ob-emacs-lisp backend does not support sessions"))
    (org-babel-result-cond result-params
      (let ((print-level nil)
            (print-length nil))
        (if (or (member "scalar" result-params)
                (member "verbatim" result-params))
            (format "%S" result)
          (format "%s" result)))
      (org-babel-reassemble-table
       result
       (org-babel-pick-name (cdr (assq :colname-names params))
                            (cdr (assq :colnames params)))
       (org-babel-pick-name (cdr (assq :rowname-names params))
                            (cdr (assq :rownames params)))))))