Function: org-babel-expand-body:lisp

org-babel-expand-body:lisp is a byte-compiled function defined in ob-lisp.el.gz.

Signature

(org-babel-expand-body:lisp BODY PARAMS)

Documentation

Expand BODY according to PARAMS, return the expanded body.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ob-lisp.el.gz
(defun org-babel-expand-body:lisp (body params)
  "Expand BODY according to PARAMS, return the expanded body."
  (let* ((vars (org-babel--get-vars params))
	 (result-params (cdr (assq :result-params params)))
	 (print-level nil) (print-length nil)
         (prologue (cdr (assq :prologue params)))
         (epilogue (cdr (assq :epilogue params)))
	 (body (if (null vars) (org-trim body)
		 (concat "(let ("
			 (mapconcat
			  (lambda (var)
			    (format "(%S (quote %S))" (car var) (cdr var)))
			  vars "\n      ")
			 ")\n"
                         (and prologue (concat prologue "\n"))
                         body
                         (and epilogue (concat "\n" epilogue "\n"))
                         ")"))))
    (if (or (member "code" result-params)
	    (member "pp" result-params))
	(format "(pprint %s)" body)
      body)))