Function: org-datetree-find-iso-week-create

org-datetree-find-iso-week-create is an autoloaded and byte-compiled function defined in org-datetree.el.gz.

Signature

(org-datetree-find-iso-week-create D &optional KEEP-RESTRICTION)

Documentation

Find or create an ISO week entry for date D.

Compared to org-datetree-find-date-create this function creates entries ordered by week instead of months. When it is nil, the buffer will be widened to make sure an existing date tree can be found. If it is the symbol subtree-at-point, then the tree will be built under the headline at point.

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-datetree.el.gz
;;;###autoload
(defun org-datetree-find-iso-week-create (d &optional keep-restriction)
  "Find or create an ISO week entry for date D.
Compared to `org-datetree-find-date-create' this function creates
entries ordered by week instead of months.
When it is nil, the buffer will be widened to make sure an existing date
tree can be found.  If it is the symbol `subtree-at-point', then the tree
will be built under the headline at point."
  (setq-local org-datetree-base-level 1)
  (save-restriction
    (if (eq keep-restriction 'subtree-at-point)
	(progn
	  (unless (org-at-heading-p) (error "Not at heading"))
	  (widen)
	  (org-narrow-to-subtree)
	  (setq-local org-datetree-base-level
		      (org-get-valid-level (org-current-level) 1)))
      (unless keep-restriction (widen))
      ;; Support the old way of tree placement, using a property
      (let ((prop (org-find-property "WEEK_TREE")))
	(when prop
	  (goto-char prop)
	  (setq-local org-datetree-base-level
		      (org-get-valid-level (org-current-level) 1))
	  (org-narrow-to-subtree))))
    (goto-char (point-min))
    (require 'cal-iso)
    (let* ((year (calendar-extract-year d))
	   (month (calendar-extract-month d))
	   (day (calendar-extract-day d))
	   (time (org-encode-time 0 0 0 day month year))
	   (iso-date (calendar-iso-from-absolute
		      (calendar-absolute-from-gregorian d)))
	   (weekyear (nth 2 iso-date))
	   (week (nth 0 iso-date)))
      ;; ISO 8601 week format is %G-W%V(-%u)
      (org-datetree--find-create
       "\\([12][0-9]\\{3\\}\\)"
       weekyear nil nil (format-time-string "%G" time) t)
      (org-datetree--find-create
       "%d-W\\([0-5][0-9]\\)"
       weekyear week nil (format-time-string "%G-W%V" time) t)
      ;; For the actual day we use the regular date instead of ISO week.
      (org-datetree--find-create
       "%d-%02d-\\([0123][0-9]\\) \\w+" year month day nil t))))