Function: org-feed-parse-rss-feed

org-feed-parse-rss-feed is a byte-compiled function defined in org-feed.el.gz.

Signature

(org-feed-parse-rss-feed BUFFER)

Documentation

Parse BUFFER for RSS feed entries.

Returns a list of entries, with each entry a property list, containing the properties :guid and :item-full-text.

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-feed.el.gz
(defun org-feed-parse-rss-feed (buffer)
  "Parse BUFFER for RSS feed entries.
Returns a list of entries, with each entry a property list,
containing the properties `:guid' and `:item-full-text'."
  (require 'xml)
  (let ((case-fold-search t)
	entries beg end item guid entry)
    (with-current-buffer buffer
      (widen)
      (goto-char (point-min))
      (while (re-search-forward "<item\\>.*?>" nil t)
	(setq beg (point)
	      end (and (re-search-forward "</item>" nil t)
		       (match-beginning 0)))
	(setq item (buffer-substring beg end)
	      guid (if (string-match "<guid\\>.*?>\\(\\(?:.\\|\n\\)*?\\)</guid>" item)
		       (xml-substitute-special (match-string-no-properties 1 item))))
	(setq entry (list :guid guid :item-full-text item))
	(push entry entries)
	(widen)
	(goto-char end))
      (nreverse entries))))