Function: org-table-overlay-coordinates

org-table-overlay-coordinates is an interactive and byte-compiled function defined in org-table.el.gz.

Signature

(org-table-overlay-coordinates)

Documentation

Add overlays to the table at point, to show row/column coordinates.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-table.el.gz
(defun org-table-overlay-coordinates ()
  "Add overlays to the table at point, to show row/column coordinates."
  (interactive)
  (mapc 'delete-overlay org-table-coordinate-overlays)
  (setq org-table-coordinate-overlays nil)
  (save-excursion
    (let ((id 0) (ih 0) hline eol str ov)
      (goto-char (org-table-begin))
      (while (org-at-table-p)
        (setq eol (line-end-position))
        (setq ov (make-overlay (line-beginning-position)
                               (1+ (line-beginning-position))))
	(push ov org-table-coordinate-overlays)
	(setq hline (looking-at org-table-hline-regexp))
	(setq str (if hline (format "I*%-2d" (setq ih (1+ ih)))
		    (format "%4d" (setq id (1+ id)))))
	(org-overlay-before-string ov str 'org-special-keyword 'evaporate)
	(when hline
	  (let ((ic 0))
	    (while (re-search-forward "[+|]\\(-+\\)" eol t)
	      (cl-incf ic)
	      (let* ((beg (1+ (match-beginning 0)))
		     (s1 (format "$%d" ic))
		     (s2 (org-number-to-letters ic))
		     (str (if (eq t org-table-use-standard-references) s2 s1))
		     (ov (make-overlay beg (+ beg (length str)))))
		(push ov org-table-coordinate-overlays)
		(org-overlay-display ov str 'org-special-keyword 'evaporate)))))
	(forward-line)))))