Function: org-tag-alist-to-string

org-tag-alist-to-string is a byte-compiled function defined in org.el.gz.

Signature

(org-tag-alist-to-string ALIST &optional SKIP-KEY)

Documentation

Return tag string associated to ALIST.

ALIST is an alist, as defined in org-tag-alist or org-tag-persistent-alist, or produced with org-tag-string-to-alist.

Return value is a string suitable as a value for "TAGS" keyword.

When optional argument SKIP-KEY is non-nil, skip selection keys next to tags.

Source Code

;; Defined in /usr/src/emacs/lisp/org/org.el.gz
(defun org-tag-alist-to-string (alist &optional skip-key)
  "Return tag string associated to ALIST.

ALIST is an alist, as defined in `org-tag-alist' or
`org-tag-persistent-alist', or produced with
`org-tag-string-to-alist'.

Return value is a string suitable as a value for \"TAGS\"
keyword.

When optional argument SKIP-KEY is non-nil, skip selection keys
next to tags."
  (mapconcat (lambda (token)
	       (pcase token
		 (`(:startgroup) "{")
		 (`(:endgroup) "}")
		 (`(:startgrouptag) "[")
		 (`(:endgrouptag) "]")
		 (`(:grouptags) ":")
		 (`(:newline) "\\n")
		 ((and
		   (guard (not skip-key))
		   `(,(and tag (pred stringp)) . ,(and key (pred characterp))))
		  (format "%s(%c)" tag key))
		 (`(,(and tag (pred stringp)) . ,_) tag)
		 (_ (user-error "Invalid tag token: %S" token))))
	     alist
	     " "))