Function: posframe--set-frame-size

posframe--set-frame-size is a byte-compiled function defined in posframe.el.

Signature

(posframe--set-frame-size SIZE-INFO)

Documentation

Set POSFRAME's size based on SIZE-INFO.

Source Code

;; Defined in ~/.emacs.d/elpa/posframe-20260415.14/posframe.el
(defun posframe--set-frame-size (size-info)
  "Set POSFRAME's size based on SIZE-INFO."
  (let ((posframe (plist-get size-info :posframe))
        (width (plist-get size-info :width))
        (height (plist-get size-info :height))
        (max-width (plist-get size-info :max-width))
        (max-height (plist-get size-info :max-height))
        (min-width (plist-get size-info :min-width))
        (min-height (plist-get size-info :min-height)))
    (cond
     ((and width height)
      (set-frame-size posframe
                      (* (default-font-width) width)
                      (* (default-line-height) height)
                      t))
     (height (set-frame-height posframe height))
     (width (set-frame-width posframe width)))
    (unless (and height width)
      (posframe--fit-frame-to-buffer
       posframe max-height min-height max-width min-width
       (cond (width 'vertically)
             (height 'horizontally))))
    (setq-local posframe--last-posframe-size size-info)))