Function: pr-interface-ps

pr-interface-ps is a byte-compiled function defined in printing.el.gz.

Signature

(pr-interface-ps PS-DESPOOL PS-DIRECTORY PS-FILE PS-FILE-UP PS-REGION PS-MODE PS-BUFFER)

Source Code

;; Defined in /usr/src/emacs/lisp/printing.el.gz
(defun pr-interface-ps (ps-despool ps-directory ps-file ps-file-up ps-region
				   ps-mode ps-buffer)
  (condition-case data
      (let ((outfile (or (and (eq pr-i-process 'file) pr-i-ps-as-is)
			 (pr-i-ps-send))))
	(cond
	 ((and pr-i-despool pr-spool-p)
	  (pr-interface-save
	   (funcall ps-despool outfile))
	  (setq pr-i-despool nil)
	  (pr-update-checkbox 'pr-i-despool))
	 ((eq pr-i-process 'directory)
	  (pr-i-directory)
	  (pr-interface-save
	   (funcall ps-directory
		    pr-i-n-up pr-i-directory pr-i-regexp outfile)))
	 ((eq pr-i-process 'file)
	  (cond ((or (file-directory-p pr-i-ps-file)
		     (not (file-readable-p pr-i-ps-file)))
		 (error "Please specify a readable PostScript file"))
		(pr-i-ps-as-is
		 (pr-interface-save
		  (funcall ps-file pr-i-ps-file)))
		(t
		 (pr-interface-save
		  (funcall ps-file-up pr-i-n-up pr-i-ps-file outfile)))
		))
	 ((eq pr-i-process 'buffer)
	  (pr-interface-save
	   (cond (pr-i-region
		  (let ((pr-auto-mode pr-i-mode))
		    (funcall ps-region pr-i-n-up outfile)))
		 (pr-i-mode
		  (let (pr-auto-region)
		    (funcall ps-mode pr-i-n-up outfile)))
		 (t
		  (let (pr-auto-mode pr-auto-region)
		    (funcall ps-buffer pr-i-n-up outfile)))
		 )))
	 (t
	  (error "Internal error: `pr-i-process' = %S" pr-i-process))
	 ))
    ;; handlers
    ((quit error)
     (ding)
     (message "%s" (error-message-string data)))))