Function: preview-move-point

preview-move-point is a byte-compiled function defined in preview.el.

Signature

(preview-move-point)

Documentation

Move point out of fake-intangible areas.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/preview.el
(defun preview-move-point ()
  "Move point out of fake-intangible areas."
  (preview-check-changes)
  (let* (newlist (pt (point)) (lst (overlays-at pt)) distance)
    (setq preview-temporary-opened
          (dolist (ov preview-temporary-opened newlist)
            (and (overlay-buffer ov)
                 (eq (overlay-get ov 'preview-state) 'inactive)
                 (if (and (eq (overlay-buffer ov) (current-buffer))
                          (or (<= pt (overlay-start ov))
                              (>= pt (overlay-end ov))))
                     (preview-toggle ov t)
                   (push ov newlist)))))
    (when lst
      (if (or disable-point-adjustment
              global-disable-point-adjustment
              (preview-auto-reveal-p
               preview-auto-reveal
               (setq distance
                     (and (eq (marker-buffer preview-marker)
                              (current-buffer))
                          (- pt (marker-position preview-marker))))))
          (preview-open-overlays lst)
        (while lst
          (setq lst
                (if (and
                     (eq (overlay-get (car lst) 'preview-state) 'active)
                     (> pt (overlay-start (car lst))))
                    (overlays-at
                     (setq pt (if (and distance (< distance 0))
                                  (overlay-start (car lst))
                                (overlay-end (car lst)))))
                  (cdr lst))))
        (goto-char pt)))))