Function: preview-prepare-fast-conversion

preview-prepare-fast-conversion is a byte-compiled function defined in preview.el.

Signature

(preview-prepare-fast-conversion)

Documentation

This fixes up all parameters for fast conversion.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/preview.el
(defun preview-prepare-fast-conversion ()
  "This fixes up all parameters for fast conversion."
  (let* ((file (if (consp (car preview-ps-file))
                   (if (consp (caar preview-ps-file))
                       (car (last (caar preview-ps-file)))
                     (caar preview-ps-file))
                 (car preview-ps-file)))
         (all-files (if (and (consp (car preview-ps-file))
                             (consp (caar preview-ps-file)))
                        (caar preview-ps-file)
                      (list file))))
    (setq preview-gs-dsc (preview-dsc-parse file))
    (setq preview-gs-init-string
          ;; Add commands for revised file access controls introduced
          ;; after gs 9.27 (bug#37719)
          (concat (format "systemdict /.addcontrolpath known {%s} if "
                          (mapconcat (lambda (f)
                                       (format "/PermitFileReading %s .addcontrolpath"
                                               (preview-ps-quote-filename f)))
                                     all-files "\n"))
                  (format "{<</PermitFileReading[%s]>> setuserparams \
.locksafe} stopped pop "
                          (mapconcat #'preview-ps-quote-filename all-files ""))
                  preview-gs-init-string
                  (format " %s(r)file /.preview-ST 1 index def %s exec .preview-ST "
                          (preview-ps-quote-filename file)
                          (preview-gs-dsc-cvx 0 preview-gs-dsc))))))