Function: project-prompt-project-name

project-prompt-project-name is a byte-compiled function defined in project.el.gz.

Signature

(project-prompt-project-name)

Documentation

Prompt the user for a project, by name, that is one of the known project roots.

The project is chosen among projects known from the project list, see project-list-file. It's also possible to enter an arbitrary directory not in the list.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/project.el.gz
(defun project-prompt-project-name ()
  "Prompt the user for a project, by name, that is one of the known project roots.
The project is chosen among projects known from the project list,
see `project-list-file'.
It's also possible to enter an arbitrary directory not in the list."
  (let* ((dir-choice "... (choose a dir)")
         project--name-history
         (choices
          (let (ret)
            ;; Iterate in reverse order so project--name-history is in
            ;; the same order as project--list.
            (dolist (dir (reverse (project-known-project-roots)))
              ;; We filter out directories that no longer map to a project,
              ;; since they don't have a clean project-name.
              (when-let ((proj (project--find-in-directory dir))
                         (name (project-name proj)))
                (push name project--name-history)
                (push (cons name proj) ret)))
            (reverse ret)))
         ;; XXX: Just using this for the category (for the substring
         ;; completion style).
         (table (project--file-completion-table
                 (reverse (cons dir-choice choices))))
         (pr-name ""))
    (while (equal pr-name "")
      ;; If the user simply pressed RET, do this again until they don't.
      (setq pr-name
            (let (history-add-new-input)
              (completing-read "Select project: " table nil t nil 'project--name-history))))
    (if (equal pr-name dir-choice)
        (read-directory-name "Select directory: " default-directory nil t)
      (let ((proj (assoc pr-name choices)))
        (if (stringp proj) proj (project-root (cdr proj)))))))