Function: ps-mode--syntax-propertize-special

ps-mode--syntax-propertize-special is a byte-compiled function defined in ps-mode.el.gz.

Signature

(ps-mode--syntax-propertize-special END)

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/ps-mode.el.gz
(defun ps-mode--syntax-propertize-special (end)
  (let ((ppss (syntax-ppss))
        char)
    (cond
     ((not (nth 3 ppss)))          ;Not in (...), <~..base85..~>, or <..hex..>.
     ((eq ?\( (setq char (char-after (nth 8 ppss))))
      (save-restriction
        (narrow-to-region (point-min) end)
        (goto-char (nth 8 ppss))
        (condition-case nil
            (with-syntax-table ps-mode--string-syntax-table
              (let ((parse-sexp-lookup-properties nil))
                (forward-sexp 1))
              (put-text-property (1- (point)) (point)
                                 'syntax-table (string-to-syntax "|")))
          (scan-error (goto-char end)))))
     ((eq char ?<)
      (when (re-search-forward (if (eq ?~ (char-after (1+ (nth 8 ppss))))
                                   "~>" ">")
                               end 'move)
        (put-text-property (1- (point)) (point)
                           'syntax-table (string-to-syntax "|")))))))