Function: register-read-with-preview-traditional

register-read-with-preview-traditional is a byte-compiled function defined in register.el.gz.

Signature

(register-read-with-preview-traditional PROMPT)

Documentation

Read register name, prompting with PROMPT; possibly show existing registers.

This reads and returns the name of a register. PROMPT should be a string to prompt the user for the name. If register-alist and register-preview-delay are both non-nil, display a window listing existing registers after register-preview-delay seconds. If help-char (or a member of help-event-list) is pressed, display preview window unconditionally.

This function is used as the value of register--read-with-preview-function when register-use-preview is set to 'traditional.

Source Code

;; Defined in /usr/src/emacs/lisp/register.el.gz
(defun register-read-with-preview-traditional (prompt)
  "Read register name, prompting with PROMPT; possibly show existing registers.
This reads and returns the name of a register.  PROMPT should be a string
to prompt the user for the name.
If `register-alist' and `register-preview-delay' are both non-nil, display
a window listing existing registers after `register-preview-delay' seconds.
If `help-char' (or a member of `help-event-list') is pressed,
display preview window unconditionally.

This function is used as the value of `register--read-with-preview-function'
when `register-use-preview' is set to \\='traditional."
  (let* ((buffer "*Register Preview*")
	 (timer (when (numberp register-preview-delay)
		  (run-with-timer register-preview-delay nil
				  (lambda ()
				    (unless (get-buffer-window buffer)
				      (register-preview buffer))))))
	 (help-chars (cl-loop for c in (cons help-char help-event-list)
			      when (not (get-register c))
			      collect c)))
    (unwind-protect
	(progn
	  (while (memq (read-key (propertize prompt 'face 'minibuffer-prompt))
		       help-chars)
	    (unless (get-buffer-window buffer)
	      (register-preview buffer 'show-empty)))
          (when (or (eq ?\C-g last-input-event)
                    (eq 'escape last-input-event)
                    (eq ?\C-\[ last-input-event))
            (keyboard-quit))
	  (if (characterp last-input-event) last-input-event
	    (error "Non-character input-event")))
      (and (timerp timer) (cancel-timer timer))
      (let ((w (get-buffer-window buffer)))
        (and (window-live-p w) (delete-window w)))
      (and (get-buffer buffer) (kill-buffer buffer)))))