Function: rmail--mailing-list-message

rmail--mailing-list-message is a byte-compiled function defined in rmail.el.gz.

Signature

(rmail--mailing-list-message WHICH)

Documentation

Send a message to mailing list whose purpose is identified by WHICH.

WHICH is a symbol, one of help, unsubscribe, or post.

Source Code

;; Defined in /usr/src/emacs/lisp/mail/rmail.el.gz
;;; Mailing list support
(defun rmail--mailing-list-message (which)
  "Send a message to mailing list whose purpose is identified by WHICH.
WHICH is a symbol, one of `help', `unsubscribe', or `post'."
  (let ((header
         (cond ((eq which 'help) "List-Help")
               ((eq which 'unsubscribe) "List-Unsubscribe")
               ((eq which 'post) "List-Post")))
        (msg
         (cond ((eq which 'post)
                "Write Subject and body, then type \\[%s] to send the message.")
               (t
                "Type \\[%s] to send the message.")))
        address header-list to subject)
    (setq address (rmail-get-header header))
    (cond ((and address (string-match "<\\(mailto:[^>]*\\)>" address))
           (setq address (match-string 1 address))
           (setq header-list (rfc6068-parse-mailto-url address)
                 to (cdr (assoc-string "To" header-list t))
                 subject (or (cdr (assoc-string "Subject" header-list t)) ""))
           (rmail-start-mail nil to subject nil nil rmail-buffer)
           (message (substitute-command-keys
                     (format msg (get mail-user-agent 'sendfunc)))))
          (t
           (user-error "This message does not specify \"%s\" address"
                       header)))))