Function: sc-set-variable

sc-set-variable is a byte-compiled function defined in supercite.el.gz.

Signature

(sc-set-variable VAR)

Documentation

Set the Supercite VARIABLE.

This function mimics set-variable, except that the variable to set is determined non-interactively. The value is queried for in the minibuffer exactly the same way that set-variable does it.

You can see the current value of the variable when the minibuffer is querying you by typing \C-h. Note that the format is changed slightly from that used by set-variable -- the current value is printed just after the variable's name instead of at the bottom of the help window.

Source Code

;; Defined in /usr/src/emacs/lisp/mail/supercite.el.gz
(defun sc-set-variable (var)
  "Set the Supercite VARIABLE.
This function mimics `set-variable', except that the variable to set
is determined non-interactively.  The value is queried for in the
minibuffer exactly the same way that `set-variable' does it.

You can see the current value of the variable when the minibuffer is
querying you by typing \\`C-h'.  Note that the format is changed
slightly from that used by `set-variable' -- the current value is
printed just after the variable's name instead of at the bottom of the
help window."
  (let* ((myhelp
	  (lambda ()
	    (with-output-to-temp-buffer "*Help*"
	      (prin1 var)
	      (if (boundp var)
		  (let ((print-length 20))
		    (princ "\t(Current value: ")
		    (prin1 (symbol-value var))
		    (princ ")")))
	      (princ "\n\nDocumentation:\n")
	      (princ (substring (documentation-property
				 var
				 'variable-documentation)
				1))
	      (with-current-buffer standard-output
		(help-mode))
	      nil)))
	 (minibuffer-help-form `(funcall #',myhelp)))
    (set var (eval-minibuffer (format "Set %s to value: " var)))))