Function: sql-rename-buffer

sql-rename-buffer is an interactive and byte-compiled function defined in sql.el.gz.

Signature

(sql-rename-buffer &optional NEW-NAME)

Documentation

Rename a SQL interactive buffer.

Prompts for the new name if command is preceded by C-u (universal-argument). If no buffer name is provided, then the sql-alternate-buffer-name is used.

The actual buffer name set will be "*SQL: NEW-NAME*". If NEW-NAME is empty, then the buffer name will be "*SQL*".

Probably introduced at or before Emacs version 24.1.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/sql.el.gz
(defun sql-rename-buffer (&optional new-name)
  "Rename a SQL interactive buffer.

Prompts for the new name if command is preceded by
\\[universal-argument].  If no buffer name is provided, then the
`sql-alternate-buffer-name' is used.

The actual buffer name set will be \"*SQL: NEW-NAME*\".  If
NEW-NAME is empty, then the buffer name will be \"*SQL*\"."
  (interactive "P")

  (if (not (derived-mode-p 'sql-interactive-mode))
      (user-error "Current buffer is not a SQL interactive buffer")

    (setq sql-alternate-buffer-name
          (substring-no-properties
           (cond
            ((stringp new-name)
             new-name)
            ((consp new-name)
             (read-string "Buffer name (\"*SQL: XXX*\"; enter `XXX'): "
                          sql-alternate-buffer-name))
            (t
             sql-alternate-buffer-name))))

    (rename-buffer
     (sql-generate-unique-sqli-buffer-name sql-product
                                           sql-alternate-buffer-name)
     t)))