Function: tooltip-show-help

tooltip-show-help is a byte-compiled function defined in tooltip.el.gz.

Signature

(tooltip-show-help MSG)

Documentation

Function installed as show-help-function.

MSG is either a help string to display, or nil to cancel the display.

Source Code

;; Defined in /usr/src/emacs/lisp/tooltip.el.gz
(defun tooltip-show-help (msg)
  "Function installed as `show-help-function'.
MSG is either a help string to display, or nil to cancel the display."
  (if (and (display-graphic-p)
           ;; Tooltips can't be displayed on top of the global menu
           ;; bar on NS.
           (or (not (eq window-system 'ns))
               (not (menu-or-popup-active-p))))
      (let ((previous-help tooltip-help-message))
	(setq tooltip-help-message msg)
	(cond ((null msg)
	       ;; Cancel display.  This also cancels a delayed tip, if
	       ;; there is one.
	       (tooltip-hide))
	      ((equal previous-help msg)
	       ;; Same help as before (but possibly the mouse has
	       ;; moved or the text properties have changed).  Keep
	       ;; what we have.  If only text properties have changed,
	       ;; the tooltip won't be updated, but that shouldn't
	       ;; occur.
	       )
	      (t
	       ;; A different help.  Remove a previous tooltip, and
	       ;; display a new one, with some delay.
	       (tooltip-hide)
	       (tooltip-start-delayed-tip))))
    ;; On text-only displays, try `tooltip-show-help-non-mode'.
    (tooltip-show-help-non-mode msg)))