Function: tramp-skeleton-completion-function

tramp-skeleton-completion-function is an autoloaded macro defined in tramp-container.el.gz.

Signature

(tramp-skeleton-completion-function METHOD &rest BODY)

Documentation

Skeleton for tramp-*-completion-function with multi-hop support.

BODY is the backend specific code.

Source Code

;; Defined in /usr/src/emacs/lisp/net/tramp-container.el.gz
;;;###tramp-autoload
(defmacro tramp-skeleton-completion-function (method &rest body)
  "Skeleton for `tramp-*-completion-function' with multi-hop support.
BODY is the backend specific code."
  (declare (indent 1) (debug t))
  `(let* ((default-directory
	   (or (and (member ,method tramp-completion-multi-hop-methods)
		    tramp--last-hop-directory)
	       tramp-compat-temporary-file-directory))
	  (program (let ((tramp-verbose 0))
		     (tramp-get-method-parameter
		      (make-tramp-file-name :method ,method)
		      'tramp-login-program)))
	  (vec (when (tramp-tramp-file-p default-directory)
		 (tramp-dissect-file-name default-directory)))
	  non-essential)
     ;; We don't use connection properties, because this information
     ;; shouldn't be kept persistently.
     (with-tramp-file-property
	 vec (concat "/" ,method ":") "user-host-completions"
       ,@body)))