Function: transient--post-exit

transient--post-exit is a byte-compiled function defined in transient.el.

Signature

(transient--post-exit &optional COMMAND)

Source Code

;; Defined in ~/.emacs.d/elpa/transient-20260414.1009/transient.el
(defun transient--post-exit (&optional command)
  (transient--debug 'post-exit)
  (unless (and (eq transient--exitp 'replace)
               (or transient--prefix
                   ;; The current command could act as a prefix,
                   ;; but decided not to call `transient-setup',
                   ;; or it is prevented from doing so because it
                   ;; uses the minibuffer and the user aborted
                   ;; that.
                   (prog1 nil
                     (if (let ((obj (transient-suffix-object command)))
                           (and (slot-boundp obj 'transient)
                                (oref obj transient)))
                         ;; This sub-prefix is a transient suffix;
                         ;; go back to outer prefix, by calling
                         ;; `transient--stack-pop' further down.
                         (setq transient--exitp nil)
                       (transient--stack-zap)))))
    (remove-hook 'pre-command-hook  #'transient--pre-command)
    (remove-hook 'post-command-hook #'transient--post-command)
    (advice-remove 'recursive-edit #'transient--recursive-edit))
  (let ((replace (eq transient--exitp 'replace))
        (resume (and transient--stack
                     (not (memq transient--exitp '(replace suspend))))))
    (unless (or resume replace)
      (setq transient--showp nil))
    (setq transient--exitp nil)
    (setq transient--helpp nil)
    (setq transient--editp nil)
    (setq transient--all-levels-p nil)
    (setq transient--minibuffer-depth 0)
    (run-hooks 'transient-exit-hook)
    (when command
      (setq transient-current-prefix nil)
      (setq transient-current-command nil)
      (setq transient-current-suffixes nil)
      (setq transient--current-suffix nil))
    (cond (resume (transient--stack-pop))
          ((not replace)
           (transient--quit-kludge 'disable)
           (run-hooks 'transient-post-exit-hook)))))