Function: vc-log-mergebase

vc-log-mergebase is an autoloaded, interactive and byte-compiled function defined in vc.el.gz.

Signature

(vc-log-mergebase FILES REV1 REV2)

Documentation

Show a log of changes between the merge base of revisions REV1 and REV2.

The merge base is a common ancestor of revisions REV1 and REV2.

Probably introduced at or before Emacs version 27.1.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/vc/vc.el.gz
;;;###autoload
(defun vc-log-mergebase (_files rev1 rev2)
  "Show a log of changes between the merge base of revisions REV1 and REV2.
The merge base is a common ancestor of revisions REV1 and REV2."
  (interactive
   (vc-diff-build-argument-list-internal
    (or (ignore-errors (vc-deduce-fileset t))
        (let ((backend (or (vc-deduce-backend) (vc-responsible-backend default-directory))))
          (list backend (list (vc-call-backend backend 'root default-directory)))))))
  (let ((backend (vc-deduce-backend))
	(default-directory default-directory)
	rootdir)
    (if backend
	(setq rootdir (vc-call-backend backend 'root default-directory))
      (setq rootdir (read-directory-name "Directory for VC root-log: "))
      (setq backend (vc-responsible-backend rootdir))
      (unless backend
        (error "Directory is not version controlled")))
    (setq default-directory rootdir)
    (setq rev1 (vc-call-backend backend 'mergebase rev1 rev2))
    (vc-print-log-internal backend (list rootdir) rev1 t (or rev2 ""))))