Function: vertico-buffer--redisplay

vertico-buffer--redisplay is a byte-compiled function defined in vertico-buffer.el.

Signature

(vertico-buffer--redisplay _)

Documentation

Redisplay buffer window.

Source Code

;; Defined in ~/.emacs.d/elpa/vertico-20260811.1003/vertico-buffer.el
(defun vertico-buffer--redisplay (_)
  "Redisplay buffer window."
  (when-let* ((mbwin (active-minibuffer-window))
              ((eq (window-buffer mbwin) (current-buffer)))
              ((overlayp vertico--candidates-ov))
              (win (overlay-get vertico--candidates-ov 'window)))
    (setq-local truncate-lines (< (window-point win)
                                  (* 0.8 (window-width win)))
                vertico-count (- (/ (window-pixel-height win)
                                    (default-line-height))
                                 (if mode-line-format 2 1)))
    (set-window-point win (point))
    (set-window-hscroll win 0)
    (when vertico-buffer-hide-prompt
      (window-resize mbwin (- (window-pixel-height mbwin)) nil nil 'pixelwise)
      (set-window-vscroll mbwin 3))
    (when transient-mark-mode
      (with-silent-modifications
        (vertico--remove-face (point-min) (point-max) 'region)
        (when (use-region-p)
          (add-face-text-property
           (max (minibuffer-prompt-end) (region-beginning))
           (region-end) 'region))))
    (let ((old cursor-in-non-selected-windows)
          (new (and (eq (selected-window) mbwin)
                    (if (memq cursor-type '(nil t)) 'box cursor-type))))
      (unless (eq new old)
        (setq-local cursor-in-non-selected-windows new)
        (force-mode-line-update t)))))