Variable: japanese-LaTeX-mode-hook

japanese-LaTeX-mode-hook is a variable defined in tex-jp.el.

Value

nil

Documentation

Hook run after entering japanese-LaTeX-mode.

No problems result if this variable is not bound. add-hook automatically binds it. (This is true for all hook variables.)

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/tex-jp.el
;;;###autoload
(define-derived-mode japanese-LaTeX-mode LaTeX-mode "LaTeX"
  "Major mode in AUCTeX for editing Japanese LaTeX files."
  :syntax-table nil
  ;; The value of `major-mode' should be `LaTeX-mode', not
  ;; `japanese-LaTeX-mode', because the name `LaTeX-mode' is hard
  ;; coded in several places of AUCTeX like
  ;;   (eq major-mode 'LaTeX-mode),
  ;;   (memq major-mode '(docTeX-mode LaTeX-mode)
  ;; and so on.  By such piece of codes, `japanese-LaTeX-mode' should
  ;; simply be regarded as `LaTeX-mode'.  However, if we change
  ;; `major-mode' to `LaTeX-mode' here in the mode body,
  ;; `hack-local-variables' does not apply the directory local
  ;; variables prepared for `japanese-LaTeX-mode'.
  ;; Thus we change `major-mode' to `LaTeX-mode' after
  ;; `hack-local-variables' is done.
  :after-hook (setq major-mode 'LaTeX-mode)

  (setq japanese-TeX-mode t)

  ;; `TeX-match-style' を使うのは `TeX-update-style' の後に遅らせる。
  ;; この段階で使うと、その中で呼ぶ `TeX-style-list' の中で
  ;; `TeX-update-style' が呼ばれてしまい、local variable 等の準備が整っ
  ;; てない段階で style hook が実行されて不適な結果になることがある。
  ;; また、`TeX-update-style' は後から `find-file-hook' 中でもう一度呼
  ;; ばれるので、`TeX-parse-self' が t だと parse 処理も無駄に 2 回行
  ;; われてしまう。
  (add-hook 'TeX-update-style-hook
            #'japanese-LaTeX-guess-engine nil t)
  (setq-local LaTeX-default-style japanese-LaTeX-default-style)

  (when (and (fboundp 'font-latex-add-keywords)
             (eq TeX-install-font-lock 'font-latex-setup))
    ;; jLaTeX にはないコマンドだが、それはもう気にしなくていいだろう。
    (font-latex-add-keywords '(("textgt" "{") ("mathgt" "{"))
                             'bold-command)
    (font-latex-add-keywords '("gtfamily")
                             'bold-declaration)))