Variable: tab-bar-mode-map

tab-bar-mode-map is a variable defined in tab-bar.el.gz.

Value

Documentation

Tab Bar mode map.

Probably introduced at or before Emacs version 30.1.

Source Code

;; Defined in /usr/src/emacs/lisp/tab-bar.el.gz
(defun tab-bar--define-keys ()
  "Install key bindings to switch between tabs if so configured."
  (when tab-bar-select-tab-modifiers
    (define-key tab-bar-mode-map
                (vector (append tab-bar-select-tab-modifiers (list ?0)))
                #'tab-recent)
    (dotimes (i 8)
      (define-key tab-bar-mode-map
                  (vector (append tab-bar-select-tab-modifiers
                                  (list (+ i 1 ?0))))
                  #'tab-bar-select-tab))
    (define-key tab-bar-mode-map
                (vector (append tab-bar-select-tab-modifiers (list ?9)))
                #'tab-last))

  ;; Replace default value with a condition that supports displaying
  ;; global-mode-string in the tab bar instead of the mode line.
  (when (and (memq 'tab-bar-format-global tab-bar-format)
             (member '(global-mode-string ("" global-mode-string))
                     mode-line-misc-info))
    (setf (alist-get 'global-mode-string mode-line-misc-info)
          '(("" (:eval (if (and tab-bar-mode
                                (memq 'tab-bar-format-global
                                      tab-bar-format))
                           "" global-mode-string)))))))