Variable: woman-mode-abbrev-table

woman-mode-abbrev-table is a variable defined in woman.el.gz.

Value

#<obarray n=1>

Documentation

Abbrev table for woman-mode.

Source Code

;; Defined in /usr/src/emacs/lisp/woman.el.gz
(define-derived-mode woman-mode man-common "WoMan"
  "Turn on (most of) Man mode to browse a buffer formatted by WoMan.
WoMan is an ELisp emulation of much of the functionality of the Emacs
`man' command running the standard UN*X man and ?roff programs.
WoMan author: F.J.Wright@Maths.QMW.ac.uk
See `Man-mode' for additional details.
\\{woman-mode-map}"
  ;; FIXME: Should all this just be re-arranged so that this can just
  ;; inherit `man-common' and be done with it?
  (cl-letf (((symbol-function 'Man-build-page-list) #'ignore)
	    ((symbol-function 'Man-strip-page-headers) #'ignore)
	    ((symbol-function 'Man-unindent) #'ignore)
	    ((symbol-function 'Man-goto-page) #'ignore))
    ;; Prevent inappropriate operations:
    (delay-mode-hooks (Man-mode)))
  (setq tab-width woman-tab-width)
  (setq major-mode 'woman-mode
	mode-name "WoMan")
  ;; Don't show page numbers like Man-mode does.  (Online documents do
  ;; not have pages)
  (kill-local-variable 'mode-line-buffer-identification)
  (use-local-map woman-mode-map)
  ;; Imenu support:
  (setq imenu-generic-expression woman-imenu-generic-expression)
  (setq-local imenu-space-replacement " ")
  ;; Bookmark support.
  (setq-local bookmark-make-record-function #'woman-bookmark-make-record)
  ;; For reformat ...
  ;; necessary when reformatting a file in its old buffer:
  (setq imenu--last-menubar-index-alist nil)
  ;; necessary to avoid re-installing the same imenu:
  (setq woman-imenu-done nil)
  (if woman-imenu (woman-imenu))
  (let ((inhibit-read-only t))
    (Man-highlight-references 'WoMan-xref-man-page)))