Function: cider--compile-font-lock-keywords

cider--compile-font-lock-keywords is a byte-compiled function defined in cider-mode.el.

Signature

(cider--compile-font-lock-keywords SYMBOLS-PLIST CORE-PLIST)

Documentation

Return a list of font-lock rules for symbols in SYMBOLS-PLIST, CORE-PLIST.

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260822.1520/cider-mode.el
(defun cider--compile-font-lock-keywords (symbols-plist core-plist)
  "Return a list of font-lock rules for symbols in SYMBOLS-PLIST, CORE-PLIST."
  (let* ((cats (cider--dynamic-font-lock-symbols symbols-plist core-plist))
         (macros (plist-get cats :macros))
         (functions (plist-get cats :functions))
         (vars (plist-get cats :vars))
         (deprecated (plist-get cats :deprecated))
         (enlightened (plist-get cats :enlightened))
         (instrumented (plist-get cats :instrumented))
         (traced (plist-get cats :traced)))
    `(
      ,@(when macros
          `((,(concat (rx (or "(" "#'")) ; Can't take the value of macros.
                      "\\(" (regexp-opt macros 'symbols) "\\)")
             1 (cider--unless-local-match font-lock-keyword-face))))
      ,@(when functions
          `((,(regexp-opt functions 'symbols) 0
             (cider--unless-local-match font-lock-function-name-face))))
      ,@(when vars
          `((,(regexp-opt vars 'symbols) 0
             (cider--unless-local-match font-lock-variable-name-face))))
      ,@(when deprecated
          `((,(regexp-opt deprecated 'symbols) 0
             (cider--unless-local-match 'cider-deprecated-face) append)))
      ,@(when enlightened
          `((,(regexp-opt enlightened 'symbols) 0
             (cider--unless-local-match 'cider-enlightened-face) append)))
      ,@(when instrumented
          `((,(regexp-opt instrumented 'symbols) 0
             (cider--unless-local-match 'cider-instrumented-face) append)))
      ,@(when traced
          `((,(regexp-opt traced 'symbols) 0
             (cider--unless-local-match 'cider-traced-face) append))))))