Function: cider--locref-at-point-1

cider--locref-at-point-1 is a byte-compiled function defined in cider-repl.el.

Signature

(cider--locref-at-point-1 REG-LIST)

Documentation

Workhorse for getting locref at point.

REG-LIST is an entry in cider-locref-regexp-alist.

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260822.1520/cider-repl.el
(defun cider--locref-at-point-1 (reg-list)
  "Workhorse for getting locref at point.
REG-LIST is an entry in `cider-locref-regexp-alist'."
  (beginning-of-line)
  ;; `seq-let' (rather than a `pcase' pattern) so a user-customized entry with
  ;; missing trailing fields still binds them to nil, as the old `nth' reads did.
  (seq-let (type regexp highlight var file line) reg-list
    (when (re-search-forward regexp (line-end-position) t)
      (let ((highlight (or highlight 0)))
        (list
         :type type
         :highlight (cons (match-beginning highlight) (match-end highlight))
         :var  (and var
                    (replace-regexp-in-string "_" "-"
                                              (match-string-no-properties var)
                                              nil t))
         :file (and file (match-string-no-properties file))
         :line (and line (string-to-number (match-string-no-properties line))))))))