Function: cider-docview--fetch-clojuredocs-examples

cider-docview--fetch-clojuredocs-examples is a byte-compiled function defined in cider-doc.el.

Signature

(cider-docview--fetch-clojuredocs-examples)

Documentation

Fetch ClojureDocs examples for the current symbol, then show them.

Cache the result so subsequent toggles don't re-fetch.

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260822.1520/cider-doc.el
(defun cider-docview--fetch-clojuredocs-examples ()
  "Fetch ClojureDocs examples for the current symbol, then show them.
Cache the result so subsequent toggles don't re-fetch."
  (let ((buffer (current-buffer))
        (symbol cider-docview-symbol))
    (when (and cider-docview--clojuredocs-beg
               (marker-position cider-docview--clojuredocs-beg))
      (let ((inhibit-read-only t))
        (delete-region cider-docview--clojuredocs-beg (point-max))
        (save-excursion
          (goto-char (point-max))
          (insert (propertize "Fetching ClojureDocs examples..."
                              'font-lock-face 'font-lock-comment-face)
                  "\n"))))
    (cider-clojuredocs--lookup-async
     (cider-current-ns) symbol
     (lambda (dict)
       (when (buffer-live-p buffer)
         (with-current-buffer buffer
           ;; remember the result (even when empty) so we never re-fetch
           (setq-local cider-docview--clojuredocs-data (or dict (nrepl-dict)))
           (if (nrepl-dict-get cider-docview--clojuredocs-data "examples")
               (setq-local cider-docview--clojuredocs-shown t)
             (setq-local cider-docview--clojuredocs-shown nil)
             (message "No ClojureDocs examples for %s" symbol))
           (cider-docview--refresh-clojuredocs-footer)))))))