Function: cider-repl-handler

cider-repl-handler is a byte-compiled function defined in cider-repl.el.

Signature

(cider-repl-handler BUFFER)

Documentation

Make an nREPL evaluation handler for the REPL BUFFER.

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260822.1520/cider-repl.el
(defun cider-repl-handler (buffer)
  "Make an nREPL evaluation handler for the REPL BUFFER."
  (let ((show-prompt t))
    (cider-make-eval-handler
     :buffer buffer
     :on-value (lambda (value)
                 (cider-repl-emit-result buffer value t))
     :on-stdout (lambda (out)
                  (dolist (f cider--repl-stdout-functions)
                    (funcall f buffer out))
                  (cider-repl-emit-stdout buffer out))
     :on-stderr (lambda (err)
                  (dolist (f cider--repl-stderr-functions)
                    (funcall f buffer err))
                  (cider-repl-emit-stderr buffer err))
     :on-done (lambda ()
                (cider-repl--finalize-result buffer)
                (when show-prompt
                  (cider-repl-emit-prompt buffer))
                (when cider-repl-buffer-size-limit
                  (cider-repl-maybe-trim-buffer buffer))
                (cider-repl--auto-inspect-last-result buffer)
                (dolist (f cider--repl-done-functions)
                  (funcall f buffer)))
     :on-content-type (lambda (value content-type)
                        (if-let* ((content-attrs (cadr content-type))
                                  (content-type* (car content-type))
                                  (handler (cdr (assoc content-type*
                                                       cider-repl-content-type-handler-alist))))
                            (setq show-prompt (funcall handler content-type buffer value nil t))
                          (cider-repl-emit-result buffer value t t)))
     :on-truncated (lambda ()
                     (cider-repl-emit-stderr buffer "\n... output truncated ...\n")))))