Function: cider-stacktrace-emit-indented

cider-stacktrace-emit-indented is a byte-compiled function defined in cider-stacktrace.el.

Signature

(cider-stacktrace-emit-indented TEXT &optional INDENT FILL FONTIFY)

Documentation

Insert TEXT, and optionally FILL and FONTIFY as clojure the entire block.

INDENT is a string to insert before each line. When INDENT is nil, first line is not indented and INDENT defaults to a white-spaced string with length given by current-column.

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260822.1520/cider-stacktrace.el
(defun cider-stacktrace-emit-indented (text &optional indent fill fontify)
  "Insert TEXT, and optionally FILL and FONTIFY as clojure the entire block.
INDENT is a string to insert before each line.  When INDENT is nil, first
line is not indented and INDENT defaults to a white-spaced string with
length given by `current-column'."
  (let ((text (if fontify
                  (cider-font-lock-as-clojure text)
                text))
        (do-first indent)
        (indent (or indent (make-string (current-column) ? )))
        (beg (point)))
    (insert text)
    (goto-char beg)
    (when do-first
      (insert indent))
    (forward-line)
    (while (not (eobp))
      (insert indent)
      (forward-line))
    (when (and fill cider-stacktrace-fill-column)
      ;; Bind rather than `setq-local' so the error buffer isn't left with a
      ;; stray `fill-prefix'/`fill-column' after rendering.
      (let ((fill-column (if (numberp cider-stacktrace-fill-column)
                             cider-stacktrace-fill-column
                           fill-column))
            (fill-prefix indent))
        (fill-region beg (point))))))