Function: denote--directory-all-files-recursively

denote--directory-all-files-recursively is a byte-compiled function defined in denote.el.

Signature

(denote--directory-all-files-recursively)

Documentation

Return list of all files in variable denote-directories.

Avoids traversing dotfiles (unconditionally) and whatever matches denote-excluded-directories-regexp.

Source Code

;; Defined in ~/.emacs.d/elpa/denote-4.2.3/denote.el
(defun denote--directory-all-files-recursively ()
  "Return list of all files in variable `denote-directories'.
Avoids traversing dotfiles (unconditionally) and whatever matches
`denote-excluded-directories-regexp'."
  (let* ((directories (denote-directories))
         (predicate-fn
          (lambda (file)
            (let ((rel (denote--get-file-name-relative-to-directories file directories)))
              (cond
               ((string-match-p "\\`\\." rel) nil)
               ((string-match-p "/\\." rel) nil)
               ((denote--exclude-directory-regexp-p rel) nil)
               ((file-readable-p file)))))))
    (apply #'append
           (mapcar
            (lambda (directory)
              (directory-files-recursively
               directory
               directory-files-no-dot-files-regexp
               :include-directories
               predicate-fn
               :follow-symlinks))
            directories))))