Function: eglot--on-shutdown

eglot--on-shutdown is a byte-compiled function defined in eglot.el.gz.

Signature

(eglot--on-shutdown SERVER)

Documentation

Called by jsonrpc.el when SERVER is already dead.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/eglot.el.gz
(defun eglot--on-shutdown (server)
  "Called by jsonrpc.el when SERVER is already dead."
  ;; Turn off `eglot--managed-mode' where appropriate.
  (dolist (buffer (eglot--managed-buffers server))
    (let (;; Avoid duplicate shutdowns (github#389)
          (eglot-autoshutdown nil))
      (eglot--when-live-buffer buffer (eglot--managed-mode-off))))
  ;; Kill any expensive watches
  (maphash (lambda (_id watch-descriptors)
             (dolist (watch-desc watch-descriptors)
               (file-notify-rm-watch watch-desc)))
           (eglot--file-watches server))
  ;; Sever the project/server relationship for `server'
  (setf (gethash (eglot--project server) eglot--servers-by-project)
        (delq server
              (gethash (eglot--project server) eglot--servers-by-project)))
  (maphash (lambda (f s)
             (when (eq s server) (remhash f eglot--servers-by-xrefed-file)))
           eglot--servers-by-xrefed-file)
  ;; Cleanup entries in 'flymake-list-only-diagnostics'
  (setq flymake-list-only-diagnostics
        (cl-delete-if
         (lambda (x) (eq server
                         (get-text-property 0 'eglot--server (car x))))
         flymake-list-only-diagnostics))
  ;; Cleanup progress reporters
  (maphash (lambda (_ r)
             (unless (eq (car r) 'eglot--mode-line-reporter )
               (progress-reporter-done r)))
           (eglot--progress-reporters server))
  (cond ((eglot--shutdown-requested server)
         t)
        ((not (eglot--inhibit-autoreconnect server))
         (eglot--warn "Reconnecting after unexpected server exit.")
         (eglot-reconnect server))
        ((timerp (eglot--inhibit-autoreconnect server))
         (eglot--warn "Not auto-reconnecting, last one didn't last long."))))