Function: eudc-ldap-get-field-list

eudc-ldap-get-field-list is an interactive and byte-compiled function defined in eudcb-ldap.el.gz.

Signature

(eudc-ldap-get-field-list DUMMY &optional OBJECTCLASS)

Documentation

Return a list of valid attribute names for the current server.

OBJECTCLASS is the LDAP object class for which the valid attribute names are returned. Default to person.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/net/eudcb-ldap.el.gz
(defun eudc-ldap-get-field-list (_dummy &optional objectclass)
  "Return a list of valid attribute names for the current server.
OBJECTCLASS is the LDAP object class for which the valid
attribute names are returned.  Default to `person'."
  (interactive)
  (or eudc-server
      (call-interactively 'eudc-set-server))
  (let ((plist (copy-sequence
                (alist-get eudc-server ldap-host-parameters-alist
                           nil nil #'equal))))
    (plist-put plist 'scope 'subtree)
    (plist-put plist 'sizelimit '1)
    (let ((ldap-host-parameters-alist
           (list (cons eudc-server plist))))
      (mapcar #'eudc-ldap-cleanup-record-filtering-addresses
	      (ldap-search
	       (eudc-ldap-format-query-as-rfc1558
                (list (cons 'objectclass
			    (or objectclass
                                "person"))))
	       eudc-server nil t)))))