Function: footnote--refresh-footnotes

footnote--refresh-footnotes is a byte-compiled function defined in footnote.el.gz.

Signature

(footnote--refresh-footnotes &optional INDEX-REGEXP)

Documentation

Redraw all footnotes.

You must call this or arrange to have this called after changing footnote styles.

Source Code

;; Defined in /usr/src/emacs/lisp/mail/footnote.el.gz
(defun footnote--refresh-footnotes (&optional index-regexp)
  "Redraw all footnotes.
You must call this or arrange to have this called after changing
footnote styles."
  (let ((fn-regexp (footnote--current-regexp index-regexp)))
    (save-excursion
      (pcase-dolist (`(,fn ,text . ,pointers) footnote--markers-alist)
        ;; Take care of the pointers first.
	(dolist (locn pointers)
	  (goto-char locn)
	  ;; Try to handle the case where `footnote-start-tag' and
	  ;; `footnote-end-tag' are the same string.
	  (when (looking-at fn-regexp)
	    (replace-match
	     (propertize
	      (concat
	       footnote-start-tag
	       (footnote--index-to-string fn)
	       footnote-end-tag)
	      'footnote-number fn footnote-mouse-highlight t)
	     t t)))

        ;; Now take care of the text section
	(goto-char text)
	(when (looking-at fn-regexp)
	  (replace-match
	   (propertize
	    (concat
	     footnote-start-tag
	     (footnote--index-to-string fn)
	     footnote-end-tag)
	    'footnote-number fn)
	   t t))))))