Function: holiday-hebrew-hanukkah-1

holiday-hebrew-hanukkah-1 is a byte-compiled function defined in cal-hebrew.el.gz.

Signature

(holiday-hebrew-hanukkah-1 Y &optional ALL)

Documentation

Return dates related to Hanukkah in Year.

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/cal-hebrew.el.gz
(defun holiday-hebrew-hanukkah-1 (y &optional all)
  "Return dates related to Hanukkah in Year."
  (let* ((h-y (calendar-extract-year
               (calendar-hebrew-from-absolute
                (calendar-absolute-from-gregorian (list 11 30 y)))))
         (abs-h (calendar-hebrew-to-absolute (list 9 25 h-y)))
         (ord ["first" "second" "third" "fourth" "fifth" "sixth"
               "seventh" "eighth"]))
    (if (or all calendar-hebrew-all-holidays-flag)
        (append
         (list
          (list (calendar-gregorian-from-absolute (1- abs-h))
                "Erev Hanukkah"))
         (let (han)
           (dotimes (i 8)
             (push (list
                    (calendar-gregorian-from-absolute (+ abs-h i))
                    (format "Hanukkah (%s day)" (aref ord i)))
                   han))
           (nreverse han)))
      (list (list (calendar-gregorian-from-absolute abs-h) "Hanukkah")))))