Function: holiday-hebrew-tisha-b-av

holiday-hebrew-tisha-b-av is a byte-compiled function defined in cal-hebrew.el.gz.

Signature

(holiday-hebrew-tisha-b-av)

Documentation

List of dates around Tisha B'Av, as visible in calendar window.

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/cal-hebrew.el.gz
;;;###holiday-autoload
(defun holiday-hebrew-tisha-b-av ()
  "List of dates around Tisha B'Av, as visible in calendar window."
  (holiday-filter-visible-calendar
   (mapcan
    (lambda (y)
      (let* ((abs-t-a (calendar-hebrew-to-absolute
                       (list 5 9 (+ y 3760))))
             (wday (% abs-t-a 7)))
        (list
         (list (calendar-gregorian-from-absolute
                (- abs-t-a (if (= wday 6) 20 21)))
               "Tzom Tammuz")
         (list (calendar-gregorian-from-absolute
                (calendar-dayname-on-or-before 6 abs-t-a))
               "Shabbat Hazon")
         (list (calendar-gregorian-from-absolute
                (if (= wday 6) (1+ abs-t-a) abs-t-a))
               "Tisha B'Av")
         (list (calendar-gregorian-from-absolute
                (calendar-dayname-on-or-before 6 (+ abs-t-a 7)))
               "Shabbat Nahamu"))))
    ;; Find years that have visible months 6, 7, or 8.
    (calendar-month-visible-p 6 2))))