Function: indian-iscii-to-ucs-region

indian-iscii-to-ucs-region is an interactive and byte-compiled function defined in ind-util.el.gz.

Signature

(indian-iscii-to-ucs-region FROM TO)

Documentation

Convert the ISCII characters in the region to UCS.

Return new end position.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/language/ind-util.el.gz
(defun indian-iscii-to-ucs-region (from to)
  "Convert the ISCII characters in the region to UCS.
Return new end position."
  (interactive "r")
  ;; only Devanagari is supported now.
  (save-excursion
    (save-restriction
      (narrow-to-region from to)
      (goto-char (point-min))
      (let* ((current-repertory is13194-default-repertory)
	     (current-hashtable
	      (intern (concat "is13194-to-ucs-"
			      (symbol-name current-repertory) "-hashtbl")))
	     (current-regexp
	      (intern (concat "is13194-to-ucs-"
			      (symbol-name current-repertory) "-regexp")))
	     (re (eval current-regexp))
	     (hash (eval current-hashtable)))
	(while (re-search-forward re nil t)
	  (replace-match (gethash (match-string 0) hash ""))))
      (point-max))))