Function: lisp--el-match-keyword@llama

lisp--el-match-keyword@llama is a byte-compiled function defined in llama.el.

Signature

(lisp--el-match-keyword@llama LIMIT)

Documentation

Highlight symbols following "(##" the same as if they followed "(".

Source Code

;; Defined in ~/.emacs.d/elpa/llama-20261001.1538/llama.el
(defun lisp--el-match-keyword@llama (limit)
  "Highlight symbols following \"(##\" the same as if they followed \"(\"."
  (catch 'found
    (while (re-search-forward
            (concat "(\\(?:## ?\\)?\\("
                    (static-if (get 'lisp-mode-symbol 'rx-definition) ;>= 29.1
                        (rx lisp-mode-symbol)
                      lisp-mode-symbol-regexp)
                    "\\)\\_>")
            limit t)
      (let ((sym (static-if (fboundp 'shorthands-intern-soft) ;~= 32.0.50
                     (shorthands-intern-soft (match-string 1))
                   (intern-soft (match-string 1)))))
        (when (and (or (special-form-p sym)
                       (macrop sym)
                       (get sym 'font-lock-keyword)) ;~= 32.0.50 and morlock
                   (not (get sym 'no-font-lock-keyword))
                   (lisp--el-funcall-position-p (match-beginning 0)))
          (throw 'found t))))))