Function: lm-report-bug

lm-report-bug is an interactive and byte-compiled function defined in lisp-mnt.el.gz.

Signature

(lm-report-bug TOPIC)

Documentation

Report a bug in the package currently being visited to its maintainer.

Prompts for bug subject TOPIC. Leaves you in a mail buffer.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/emacs-lisp/lisp-mnt.el.gz
(defun lm-report-bug (topic)
  "Report a bug in the package currently being visited to its maintainer.
Prompts for bug subject TOPIC.  Leaves you in a mail buffer."
  (interactive "sBug Subject: ")
  (require 'emacsbug)
  (let ((package (lm-get-package-name))
	(addr (car (lm-maintainers)))
	(version (lm-version)))
    (compose-mail (if addr
		      (concat (car addr) " <" (cdr addr) ">")
		    report-emacs-bug-address)
		  topic)
    (goto-char (point-max))
    (insert "\nIn " package)
    (if version
	(insert " version " version))
    (newline 2)
    (message "%s"
     (substitute-command-keys "Type \\[mail-send] to send bug report."))))