Function: magit-read-starting-point

magit-read-starting-point is a byte-compiled function defined in magit-git.el.

Signature

(magit-read-starting-point PROMPT &optional BRANCH DEFAULT)

Source Code

;; Defined in ~/.emacs.d/elpa/magit-20260822.1158/magit-git.el
(defun magit-read-starting-point (prompt &optional branch default)
  (or (minibuffer-with-setup-hook #'magit--minibuf-default-add-commit
        (magit-completing-read
         (concat prompt
                 (and branch
                      (if (bound-and-true-p ivy-mode)
                          ;; Ivy-mode strips faces from prompt.
                          (format  " `%s'" branch)
                        (concat " " (magit--propertize-face
                                     branch 'magit-branch-local))))
                 " starting at")
         (let ((refnames (magit-list-refnames)))
           (when-let ((upstream (magit-get-upstream-branch)))
             (setq refnames (cons upstream (delete upstream refnames))))
           (nconc refnames
                  (list "HEAD")
                  (directory-files (magit-gitdir) nil "_HEAD\\'")))
         nil 'any nil 'magit-revision-history
         (or default (magit--default-starting-point))))
      (user-error "Nothing selected")))