Function: markdown-ts--fill-html-comment

markdown-ts--fill-html-comment is a byte-compiled function defined in markdown-ts-mode.el.gz.

Signature

(markdown-ts--fill-html-comment NODE JUSTIFY)

Documentation

Fill HTML comment NODE, aligning continuation lines.

Return t if NODE is a comment and was filled, nil otherwise. JUSTIFY is as in fill-paragraph.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/markdown-ts-mode.el.gz
(defun markdown-ts--fill-html-comment (node justify)
  "Fill HTML comment NODE, aligning continuation lines.
Return t if NODE is a comment and was filled, nil otherwise.
JUSTIFY is as in `fill-paragraph'."
  (when (save-excursion
          (goto-char (treesit-node-start node))
          (looking-at-p "<!--"))
    (let ((fill-prefix (save-excursion
                         (goto-char (treesit-node-start node))
                         (make-string (+ (current-column)
                                         (length "<!-- "))
                                      ?\s)))
          (adaptive-fill-function nil)
          (fill-forward-paragraph-function #'forward-paragraph)
          (fill-paragraph-function nil))
      (save-restriction
        (narrow-to-region (treesit-node-start node)
                          (treesit-node-end node))
        (fill-paragraph justify))
      t)))