Function: org-babel-execute:scheme

org-babel-execute:scheme is a byte-compiled function defined in ob-scheme.el.gz.

Signature

(org-babel-execute:scheme BODY PARAMS)

Documentation

Execute a block of Scheme code with org-babel.

This function is called by org-babel-execute-src-block.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ob-scheme.el.gz
(defun org-babel-execute:scheme (body params)
  "Execute a block of Scheme code with org-babel.
This function is called by `org-babel-execute-src-block'."
  (let* ((source-buffer (current-buffer))
	 (source-buffer-name (replace-regexp-in-string ;; zap surrounding *
			      "^ ?\\*\\([^*]+\\)\\*" "\\1"
			      (buffer-name source-buffer))))
    (save-excursion
      (let* ((result-type (cdr (assq :result-type params)))
	     (impl (org-babel-scheme--get-impl params))
             (host (cdr (assq :host params)))
             (port (cdr (assq :port params)))
	     (session (org-babel-scheme-make-session-name
		       source-buffer-name (cdr (assq :session params)) impl))
	     (full-body (org-babel-expand-body:scheme body params))
	     (result-params (cdr (assq :result-params params)))
	     (result
	      (org-babel-scheme-execute-with-geiser
	       full-body		       ; code
	       (string= result-type "output")  ; output?
	       impl			       ; implementation
	       (and (not (string= session "none")) session) ; session
               host ; REPL host
               port))) ; REPL port
	(let ((table
	       (org-babel-reassemble-table
		result
		(org-babel-pick-name (cdr (assq :colname-names params))
				     (cdr (assq :colnames params)))
		(org-babel-pick-name (cdr (assq :rowname-names params))
				     (cdr (assq :rownames params))))))
	  (org-babel-result-cond result-params
	    result
	    (org-babel-scheme--table-or-string table)))))))